Thread: RCON Command to Shuffle Teams

move everyone to spectator, then use auto_join_team

teamswitchdelay 0;
for (local.i = 1; local.i <= $player.size; local.i++) {
    local.player = $player[local.i];
    local.player spectator;
}
wait 1;
for (local.i = 1; local.i <= $player.size; local.i++) {
    local.player = $player[local.i];
    local.player auto_join_team;
    //local.player primarydmweapon sniper;
    waitframe;
}

you can uncomment local.player primarydmweapon sniper if you want everyone to spawn fast without having to select a weapon first, but it will auto choose the sniper rifle.

auto_join_team might not be perfect but it still do the job in his way, i mean, is not like you will use it more than once per map.
i used that method years ago for my clan, and i can tell you, when you use it it really feels like a random shuffle.

anyways, here is something better :)

main:
    teamswitchdelay 0;
    for (local.i = 1; local.i <= $player.size; local.i++) {
        local.player = $player[local.i];
        local.player spectator;
    }
    wait 1
    for (local.i = 1; local.i <= $player.size; local.i++) {
        local.array[local.i] = local.i;
    }

    local.array = waitthread Shuffle local.array local.array[1] local.array.size;

    for (local.i = 1; local.i <= local.array.size; local.i++) {
        local.player = $player[local.array[local.i]];
        if (local.i % 2)
            local.player join_team allies;
        else
            local.player join_team axis;
        //local.player primarydmweapon sniper;
        //local.player respawn;
    }
end;

Shuffle local.array local.lower local.upper:
    local.bounds = local.lower::local.upper;
    for (local.i = local.bounds[2]; local.bounds[1] <= local.i; local.i--) {
        local.swapIdx = randomint(abs(local.i)) + local.bounds[1];
        local.tmp = local.array[local.i];
        local.array[local.i] = local.array[local.swapIdx];
        local.array[local.swapIdx] = local.tmp;
    }
end local.array;

The Shuffle part is a modified version of the Shuffle script from Sor's framework.

This one is very simple:

main:

//move all players to spectator
$player join_team spectator


for (local.i = 1; local.i <= $player.size; local.i++)
{
	local.player = $player[local.i];

	if(local.player == NULL)
	end

	local.number = randomint(2) + 1

	if(local.number == 1)
	{
		local.player join_team allies
	}
	else
	{
		local.player join_team axis
	}
}



end

i know auto_join_team makes you join the side with fewer players, but still, if you run the script only one time you will get players sorted "randomly", no matter if is predefined or predictable, if you use it only one time you will get the "feeling" of randomness.
if you run it two or more times you will probably get the same result again or everyone switched to the opposite team, i think.
and you're right, shuffling the players array is a better way to do it


@DoubleKill that won't work, using just randomint doesn't assure you that the players will be distributed evenly.

You can use it to include several instructions on one line, but you don't need it if you don't. E.g:

local.player give local.item; local.player use local.item

Just some people prefer to use it because of other languages.

That line just adds local.lower and local.upper to an array (starting at index 1).

e.g.

local.array = "hey"::$someentity::12